Anexo III Comandos Ansys

Vista previa del material en texto

ANEXO III. FICHEROS DE COMANDOS PARA ANSYS 
I. PANDEO DE EULER 
I.a) Pandeo de Euler con BEAM189 
!----------------------------- 
! -Pandeo no lineal- 
!----------------------------- 
 
FINISH 
/CLEAR 
 
!IMPORTANTE: 
Los valores modificables para mejorar la convergencia son el factor de 
amplificación de UPGEOM y/o el valor de carga del análisis NO LINEAL, 
además del tipo de elemento 
 
/FILNAME,NL_BEAM189,1 
/TITLE,ENSAYO_EULER_NOLINEAL 
 
/prep7 
 
L=1000 
h=30 
b=10 
 
!Definición de keypoints 
!----------------------- 
k,1,0,0,0 
k,2,0,L,0 
 
!líneas 
!------ 
l,1,2 
 
!Definición de elementos 
!----------------------- 
ET,1,BEAM189 !Elemento 3D elástico 
KEYOPT,1,1,0 
 
!Definición de la sección 
!------------------------ 
SECTYPE,1,beam,RECT,barra,0 
SECOFFSET,CENT,0,0, , , , , 
SECDATA,b,h, , , 
 
!Definición material 1 (acero) 
!----------------------------- 
MP,EX,1,21e4 
MP,PRXY,1,0.3 
MP,DENS,1,7800e-9 
162 Proyecto Fin de Carrera Anexo III 
 
!Propiedades de las líneas 
!------------------------- 
LSEL, , , ,1 
LATT,1,1,1, , , , 
 
!Numero de divisiones 
!14 elementos 
LESIZE,1, , ,14, , , , , !nº par de elementos para que haya un nº 
impar de nodos (15) y por tanto un nodo en el centro de la barra 
 
!Mallado 
!------- 
allsel 
lmesh, all 
 
/VIEW, ,1,1,1 !Vista ISOMÉTRICA 
/SHRINK,0.0 
/ESHAPE,1 
EPLOT 
/EFACET,1 
/RATIO,1,1.0,1.0 
/CFORMAT,32,0 
/WAIT,2 
 
!----------------- 
!Análisis estático 
!----------------- 
/Solu 
 
ANTYPE,0 
NLGEOM,off 
PSTRES,on 
 
!Condiciones de contorno en desplazamiento y carga 
!------------------------------------------------- 
 
allsel,all,KP 
DK,1,UX,0, , ,UZ,ROTX,ROTY,ROTZ, 
DK,2,all,0, , , , , , , , 
KSEL, , , ,1 
FK,1,FY,1 
!ACEL,0,9.8,0 
 
allsel 
Solve 
Finish 
 
!------------------ 
!Análisis de pandeo 
!------------------ 
/Solu 
 
ANTYPE, buckle 
Pandeo de Euler 163 
 
BUCOPT,SUBSP,1, , , 
SUBOPT,8,4,0,100, ,all 
MXPAND,1, , ,yes, , 
 
Solve 
Finish 
 
/POST1 
 
SET,FIRST 
*GET,Pcrit,active,0,set,freq !Ver ayuda de *GET, en caso de análisis 
de pandeo set,freq me da el modo de pandeo que hayamos pedido 
anteriormente si entity=active 
 
!------------------ 
!ANÁLISIS NO LINEAL 
!------------------ 
/prep7 
 
!Imperfección inicial 
 
f_amp=0.5 
UPGEOM,f_amp,1,1,NL_BEAM189,rst, 
!Actualiza el modelo de E.Finitos de acuerdo a las deformaciones de 
los nodos escaladas de acuerdo al modo de pandeo del anterior análisis 
 
/Solu 
ANTYPE,0 
allsel 
FKDELE,all,all 
 
KSEL, , , ,1 
FK,1,FY,1*Pcrit 
FTRAN 
 
NLGEOM,1 !Cambia las opciones de análisis para pasar a analizar bajo 
hipótesis de grandes desplazamientos (AN. NO LINEAL) 
OUTRES,ERASE 
OUTRES,ALL,ALL 
!NSUBST,30 
NEQIT,20 
!AUTOTS,ON !AUTOTS y ARCLEN no pueden activarse a la vez 
ARCLEN,ON, , , 
!LNSRCH,ON 
 
Solve 
Finish 
 
/POST1 
 
SET,last 
PLNSOL,U,SUM,2 
/WAIT,5 
164 Proyecto Fin de Carrera Anexo III 
 
SET,FIRST 
SET,LIST 
 
!----------------------------------------------------------- 
!REPRESENTACIÓN GRÁFICA DEL DESPLAZAMIENTO FRENTE A LA CARGA 
!----------------------------------------------------------- 
/POST26 
FILE,NL_BEAM189,rst, , 
/UI,COLL,1 
!Definición de nuevas variables a representar gráficamente 
 
!EL NODO PARA EL QUE QUEREMOS REPRESENTAR LA DEFLEXIÓN DEBERÁ HABER 
SIDO LOCALIZADO EN EL LISTADO OBTENIDO DEL ANÁLISIS LINEAL (VER U_MAX) 
 
SOLU,2,NCMIT 
STORE,MERGE 
NSOL,2,16,U,X, , 
ABS,3,2, , ,UX_max 
 
SOLU,4,NCMIT 
STORE,MERGE 
PROD,4,1, , ,CARGA, , ,1*PCRIT !Multiplica la variable TIME (% de 
carga aplicado en cada iteración respecto de la total) por Pcr. 
 
PLTIME, , , 
/COLOR,CURVE,BLUE,1, , , 
/COLOR,GRBAK,WHIT, , , , 
 
XVAR,3 !Variable 3 (UX del nodo extremo) representado en el eje X 
/XRANGE,0,4 !Rango de valores del desplazamiento (en mm) 
/GTHK,Curve,4 
/AXLAB,X,Desplazamiento según X 
/AXLAB,Y,Reaccion en la "cabeza" 
PLVAR,4 !Display de la variable 4 frente a la almacenada en XVAR 
 
!PRVAR,2,4, , , , , 
II.b) Pandeo de Euler con BEAM3 
Mismo modelo que el anterior sin más que modificar la definición de elementos: 
!Definición de elementos 
!----------------------- 
ET,1,BEAM3 !Elemento 2D elástico 
KEYOPT,1,6,1 
KEYOPT,1,9,0 
 
!Definición de las constantes reales 
!----------------------------------- 
!IMPORTANTE: La definición del momento de inercia es necesaria siempre 
que la barra vaya a presentar flexión 
 
R,1,h*b,h*b*b*b/12,h, , , 
Pandeo lateral 165 
 
II. PANDEO LATERAL 
II.a) Voladizo 
!------------------------------------------------------------- 
!Ejemplo 2: -Pandeo LATERAL en viga en voladizo con Beam 189- 
!------------------------------------------------------------- 
 
FINISH 
/CLEAR 
 
/FILNAME,Voladizo_nolineal,1 
/TITLE,Pandeo Lateral -no lineal- 
 
/prep7 
 
L=5700 !Longitud de la viga 
 
!Parámetros de la sección en I 
 
w1=55 
w2=55 
w3=100 
t1=5.7 
t2=5.7 
t3=4.1 
 
!Definición del modelo sólido (keypoints) 
!---------------------------------------- 
k,1,0,0,0 
k,2,L,0,0 
k,3,0,50,0 !Keypoint auxiliar que orienta la sección (ver LATT) 
 
!líneas 
!------ 
l,1,2 
 
!Definición de elementos 
!----------------------- 
ET,1,BEAM189 !Elemento 3D elástico apropiado para analizar 
estructuras esbeltas o moderadamente "gruesas" 
 
KEYOPT,1,1,0 !Keyoption(1)=1 -> 7º gdl (alabeo) en cada nodo 
 
!Secciones 
!--------- 
SECTYPE,1,beam,I,ipe100,0 !SECTYPE,SECID,Type,Subtype,Name,REFKEY 
SECOFFSET,USER,0,0 !Aplico la carga ABAJO (Ver ayuda de SECOFFSET) 
SECDATA,w1,w2,w3,t1,t2,t3 !Ver las entradas para este tipo de 
secciones en la ayuda de SECDATA -> type:beam -> subtype: I 
 
 
166 Proyecto Fin de Carrera Anexo III 
 
!Definición material 1 (acero) 
!----------------------------- 
MP,EX,1,21e4 
MP,PRXY,1,0.3 
MP,DENS,1,7800e-9 
 
!Propiedades de las líneas 
!------------------------- 
LSEL, , , ,1 
LATT,1, ,1, ,3, ,1 
 
!Numero de divisiones 
LESIZE,1, , ,200,1.5, , , ,1 
 
!Mallado 
!------- 
allsel 
lmesh, all 
 
!Plot controls menú 
!------------------ 
 
/VIEW, ,1,1,1 !Vista ISOMÉTRICA 
/SHRINK,0.0 
/ESHAPE,1 
/EFACET,1 
/RATIO,1,1.0,1.0 
/CFORMAT,32,0 
 
/WAIT,2 
 
!----------------- 
!Análisis estático 
!----------------- 
 
/Solu 
ANTYPE,0 
 
PIVCHECK,ON 
PSTRES,ON !Necesario para posteriores análisis de pandeo 
 
!Condiciones de contorno en desplazamiento y fuerzas aplicadas 
!------------------------------------------------------------- 
allsel 
 
DK,1,ALL,0,0, , , , , , , 
 
FK,2,FY,1 !1kp=1kg 0.1kp=1N introduciendo 10 en lugar de 1 
obtendría el factor de pandeo en kp 
!ACEL,0,9.8,0 
 
allsel 
SAVE 
Pandeo lateral 167 
 
Solve 
Finish 
 
!------------------ 
!Análisis de pandeo 
!------------------ 
/Solu 
 
ANTYPE, buckle !Requiere un análisis estático previo con PSTRES,on 
BUCOPT,SUBSP,3, , , !Utiliza el método del subespacio para 
resolver el problema de autovalores/autovectores (extrae solo los 'n' 
primeros autovectores (modos de pandeo en este caso, modos de 
vibración en otro tipo de análisis, etc.). 
SUBOPT,8,4,0,100,,all !Ver ayuda de SUBOPT 
MXPAND,3, , ,yes, , 
 
Solve 
Finish 
 
/POST1 
 
SET,FIRST 
/VIEW, ,1,0,0 
PLDISP,1 
 
*GET,PCRIT,active,0,set,freq 
 
SAVE 
 
!------------------ 
!Análisis NO LINEAL 
!------------------ 
/prep7 
 
UPGEOM,0.06,1,1,Voladizo_nolineal,rst, 
FKDELE,all,all 
FK,2,FY,1.044*PCRIT 
SBCTRAN 
/WAIT,2 
 
/Solu 
 
ANTYPE,STATIC 
NLGEOM,ON 
OUTRES,all,all 
PIVCHECK,1 
NSUBST,500 
NEQIT,30 
!ARCLEN,1,0,0, 
AUTOTS,ON 
LNSRCH,ON 
Solve 
Finish 
168 Proyecto Fin de Carrera Anexo III 
 
/POST1 
 
SET,LAST 
/VIEW, ,1,1,1 
PLDISP,1 
!PLNSOL,U,SUM,2 
/WAIT,2 
 
/VIEW, ,1,0,0 
PLDISP,1 
!PLNSOL,U,SUM,2 
/WAIT,3 
 
!-------------------------------------------------------------------- 
!REPRESENTACIÓN GRÁFICA DEL DESPLAZAMIENTO LATERAL FRENTE A LA CARGA 
!-------------------------------------------------------------------- 
 
/POST26 !Módulo time-history results postprocessor. Permite 
evaluar los resultados en función del tiempo en los puntos que 
queramos, definiendo una variable en dichos puntos 
 
FILE,Voladizo_nolineal,rst, , !Fichero del que extraer los resultados 
 
/UI,COLL,1 
 
!Definición de nuevas variables a representar gráficamente 
 
SOLU,2,NCMIT 
STORE,MERGE !Merge= combinar, evalúa la nueva variable almacenada en 
los instantes de tiempo definidos en el espacio correspondiente a la 
vble. tiempo) 
!EL NODO DEL CUAL QUEREMOS OBTENER LA DEFLEXIÓN DEBERÁ HABER SIDO 
LOCALIZADO EN EL LISTADO OBTENIDO DEL ANÁLISIS LINEAL (VER U_MAX) 
NSOL,2,2,U,Z, , 
 
PROD,3,1, , ,CARGA, , ,1.044*PCRIT 
STORE,MERGE 
 
SOLU,4,NCMIT 
STORE,MERGE !Merge= combinar, evalúa la nueva variable en los 
instantes de t definidos en el espacio correspondiente a la vble. TIME 
NSOL,4,2,U,Y, , 
 
PLTIME, , , 
 
/COLOR,CURVE,BLUE,1, , , 
/COLOR,GRBAK,WHIT, , , , 
 
XVAR,4 
/XRANGE,0,125 
/AXLAB,X,Desplazamiento según Y 
/AXLAB,Y,Carga aplicada 
PLVAR,3 !Display de la variable 4 frente a la contenida en XVAR 
Pandeo lateral 169 
 
/WAIT,4 
 
XVAR,2 !Variable 2 (UX del nodo extremo) representado en el eje X 
/XRANGE,0,10 
 
/AXLAB,X,Desplazamiento según Z 
/AXLAB,Y,Carga aplicada 
 
PLVAR,3 
 
PRVAR,3,2,4 
II.b) Voladizo BEAM3 
Mismo cambio que el realizado en I.a): 
!Definición de elementos 
!----------------------- 
ET,1,BEAM3 !Elemento 2D elástico 
KEYOPT,1,6,1 
KEYOPT,1,9,0 
 
!Definición de las constantes reales 
!----------------------------------- 
R,1,1030,159200,100, , , 
II.c) Biapoyada 
Mismo modelo que II.a) sin más que modificar las condiciones de apoyo y cargas: 
/Solu 
 
!Condiciones de contorno en desplazamiento y fuerzas aplicadas 
!------------------------------------------------------------- 
allsel 
 
DK,1,UX,0, , ,UY,UZ,ROTX, , , 
DK,2,UX,0, , ,UY,UZ,ROTX, , , 
!NSEL,S,LOC,X,1,5700, , , 
F,1,MZ,-1, , , , 
F,2,MZ,1, , , , 
!ACEL,0,9.8e-3,0 
 
allsel 
SAVE 
 
Solve 
Finish 
170 Proyecto Fin de Carrera Anexo III 
 
III. ABOLLADURA 
III.a) Abolladura por cortante 
!------------------------------------ 
!Ejemplo 3: -Abolladura con SHELL 63- 
!------------------------------------ 
 
FINISH 
/CLEAR 
/FILNAME,abolladura_cortante_Nolineal,1 
/TITLE,ABOLLADURA POR CORTANTE -NO LINEAL- 
 
/prep7 
 
L=1000 !Longitud de la viga en mm 
 
!Parámetros de la sección en I 
w1=100 
w2=100 
w3=750 
t1=17 
t2=17 
t3=5 
t4=14 
 
!Definición del modelo sólido (keypoints) 
!---------------------------------------- 
k,1,0,0,0 
k,2,L,0,0 
k,3,2*L,0,0 
k,4,2*L,w3,0 
k,5,L,w3,0 
k,6,0,w3,0 
k,7,0,0,w1/2 
k,8,L,0,w1/2 
k,9,2*L,0,w1/2 
k,10,0,0,-w1/2 
k,11,L,0,-w1/2 
k,12,2*L,0,-w1/2 
k,13,0,w3,w2/2 
k,14,L,w3,w2/2 
k,15,2*L,w3,w2/2 
k,16,0,w3,-w2/2 
k,17,L,w3,-w2/2 
k,18,2*L,w3,-w2/2 
 
!líneas 
!------ 
*do,i,1,5,1 
l,i,i+1 
*enddo 
Abolladura 171 
 
l,6,1 
l,2,5 
l,1,7 
l,7,8 
l,8,9 
l,9,3 
l,3,12 
l,12,11 
l,11,10 
l,1,10 
l,6,13 
l,13,14 
l,14,15 
l,15,4 
l,4,18 
l,18,17 
l,17,16 
l,16,6 
l,14,5 
l,5,17 
l,8,2 
l,2,11 
l,14,8 
l,11,17 
l,13,7 
l,10,16 
l,15,9 
l,12,18 
 
!Áreas 
!----- 
AL,1,7,5,6 
AL,2,3,4,7 
AL,9,8,1,26 
AL,10,26,2,11 
AL,27,13,12,2 
AL,15,14,27,1 
AL,16,17,24,5 
AL,18,19,4,24 
AL,20,21,25,4 
AL,22,23,5,25 
AL,24,28,26,7 
AL,27,29,25,7 
AL,16,30,8,6 
AL,31,23,6,15 
AL,32,11,3,19 
AL,12,33,20,3 
 
!Definición de elementos 
!----------------------- 
ET,1,SHELL63 !Elemento elástico con 4 NODOS y 6 grados de libertad 
en cada nodo con. Permite cargas normales y perpendiculares a su plano 
y sirve para estudiar tanto esfuerzos de flexión como de membrana 
172 Proyecto Fin de Carrera Anexo III 
 
KEYOPT,1,1,0 
KEYOPT,1,2,1 
KEYOPT,1,3,2 
KEYOPT,1,8,1 
KEYOPT,1,11,2 
 
!Constantes reales 
!----------------- 
!Alas 
R,1,t1, , , ,0, , 
RMORE, , , , , , , 
RMORE, , , , , , , 
RMORE, , 
 
!Alma 
R,2,t3, , , ,0, , 
RMORE, , , , , , , 
RMORE, , , , , , , 
RMORE, , 
 
!Rigidizadores 
R,3,t4, , , ,0, , 
RMORE, , , , , , , 
RMORE, , , , , , , 
RMORE, , 
 
!Definición material 1 (acero) 
!----------------------------- 
MP,EX,1,21e4 
MP,PRXY,1,0.3 
MP,DENS,1,7800e-9 
 
!Propiedades de las áreas 
!------------------------ 
ASEL,S,area, ,1,2,1 
AATT,1,2,1, , , 
 
ASEL,S,area, ,3,10,1 
AATT,1,1,1, , , 
 
ASEL,S,area, ,11,16,1 
AATT,1,3,1, , , 
 
!Numero de divisiones 
LSEL,S,LINE, ,1,4,3 
LESIZE,all, , ,30, , , , ,no 
LSEL,S,LINE, ,2,5,3 
LESIZE,all, , ,30, , , , ,no 
LSEL,S,LINE, ,9,21,4 
LESIZE,all, , ,30, , , , ,no 
LSEL,S,LINE, ,10,22,4 
LESIZE,all, , ,30, , , , ,no 
LSEL,S,LINE, ,3 
Abolladura 173 
 
LESIZE,all, , ,30, , , , ,no 
LSEL,S,LINE, ,6,7,1 
LESIZE,all, , ,30, , , , ,no 
LSEL,S,LINE, ,28,33,1 
LESIZE,all, , ,30, , , , ,no 
 
LSEL,S,LINE, ,16 
LESIZE,all, , ,4, , , , ,no 
LSEL,S,LINE, ,19,20,1 
LESIZE,all, , ,4, , , , ,no 
LSEL,S,LINE, ,23,25,1 
LESIZE,all, , ,4, , , , ,no 
LSEL,S,LINE, ,6 
LESIZE,all, , ,4, , , , ,no 
LSEL,S,LINE, ,11,12,1 
LESIZE,all, , ,4, , , , ,no 
LSEL,S,LINE, ,15 
LESIZE,all, , ,4, , , , ,no 
LSEL,S,LINE, ,26,27,1 
LESIZE,all, , ,4, , , , ,no 
 
!Mallado 
!------- 
allsel 
AMAP,1,1,2,5,6 
AMAP,2,2,3,4,5 
AMAP,3,1,7,8,2 
AMAP,4,2,8,9,3 
AMAP,5,3,12,11,2 
AMAP,6,2,11,10,1 
AMAP,7,6,13,14,5 
AMAP,8,5,14,15,4 
AMAP,9,4,18,17,5 
AMAP,10,5,17,16,6 
AMAP,11,5,14,8,2 
AMAP,12,2,11,17,5 
AMAP,13,6,13,7,1 
AMAP,14,1,10,16,6 
AMAP,15,4,15,9,3 
AMAP,16,3,12,18,4 
 
Finish 
allsel 
 
!Plot controls menú 
!------------------ 
/VIEW, ,1,1,1 !Vista ISOMÉTRICA 
/SHRINK,0.0 
/ESHAPE,1 !Eligiendo la opción 1 damos volumen a la pieza 
EPLOT ! Equivale a activar el display en "size & shape" 
/EFACET,1 
/RATIO,1,1.0,1.0 
/CFORMAT,32,0 
174 Proyecto Fin de Carrera Anexo III 
 
/WAIT,2 
 
!----------------- 
!Análisis estático 
!----------------- 
/Solu 
 
ANTYPE,0 
 
PIVCHECK, 
PSTRES,ON !Necesario si se va a ejecutar un análisis de pandeo 
 
!Condiciones de contorno en desplazamiento y fuerzas aplicadas 
!------------------------------------------------------------- 
allsel 
 
DL,8,3,all,0 
DL,11,4,all,0 
DL,12,5,all,0 
DL,15,6,all,0DK,4,UZ,0 
DK,5,UZ,0 
DK,6,UZ,0 
 
FK,5,FY,-1 
 
!ACEL,0,9.8,0 
 
allsel 
SAVE 
 
Solve 
Finish 
 
¡------------------ 
!Análisis de pandeo 
!------------------ 
/Solu 
 
ANTYPE, buckle 
BUCOPT,LANB,3, , 
MXPAND,3, , ,yes, , 
 
Solve 
 
Finish 
 
/POST1 
 
SET,FIRST 
PLDISP,0 
/WAIT,4 
PLNSOL,U,Z,0,1.2, , 
Abolladura 175 
 
*GET,PCRIT,active,0,set, 
!SET,LIST 
SAVE 
/WAIT,3 
 
!------------------ 
!Análisis NO LINEAL 
!------------------ 
/prep7 
 
UPGEOM,0.5,1,1,abolladura_cortante_Nolineal,rst 
 
FK,5,FY,-2*PCRIT 
 
/Solu 
 
ANTYPE,STATIC 
!SSTIF,ON 
NLGEOM,ON 
OUTRES,all,all 
!KBC,0 !introduce el paso de carga poco a poco (linealmente) 
NSUBST,300 
NEQIT,50 
!AUTOTS,ON 
!LNSRCH,ON 
!NCNV,2,500,10000, ,300 
 
ARCLEN,ON 
ARCTRM,U,20, ,UZ 
 
Solve 
Finish 
 
/POST1 
 
/VIEW, ,1,1,1 
SET,last 
 
/DSCALE,1,5 
PLDISP,0 
/WAIT,4 
 
Finish 
 
!Gráficas 
!-------- 
 
/POST26 !Módulo time-history results postprocessor. Permite 
evaluar los resultados en función del tiempo en los puntos que 
queramos, definiendo una variable en dichos puntos 
 
FILE,abolladura_cortante_Nolineal,rst, , 
/UI,COLL,1 
176 Proyecto Fin de Carrera Anexo III 
 
!Definición de nuevas variables 
SOLU,2,NCMIT 
STORE,MERGE 
 
PROD,2,1, , ,CARGA, , ,2*PCRIT 
 
SOLU,3,NCMIT 
STORE,MERGE 
NSOL,3,600,U,Z, , 
 
ABS,4,3, , ,UZ_max 
 
SOLU,5,NCMIT 
STORE,MERGE 
NSOL,5,32,U,Y, , 
 
ABS,6,5, , ,UY_max 
 
!Defino los parámetros de las gráficas a representar 
PLTIME, , , !por defecto representa desde el 1er hasta el último punto 
 
/COLOR,CURVE,BLUE,1, , , 
/COLOR,GRBAK,WHIT, , , , 
 
XVAR,6 !Variable 4 (desplazamiento según Z del nodo extremo) 
representado en el eje X 
 
!....resto de parámetros por defecto (ver por menús TimeHist postproc 
-> settings -> graphs) 
 
/AXLAB,X,Desplazamiento UY central (mm) 
/AXLAB,Y,Carga (N) 
 
PLVAR,2 
 
/WAIT,4 
 
XVAR,4 !Variable 4 (desplazamiento según Z del nodo extremo) 
representado en el eje X 
 
!resto de parámetros por defecto (ver por menús TimeHist postproc -> 
settings -> graphs) 
 
/AXLAB,X,UZ MAXIMO (mm) 
/AXLAB,Y,Carga (N) 
 
PLVAR,2 
/WAIT,4 
 
PRVAR,2,4,6, , , , 
 
Abolladura 177 
 
III.b) Abolladura por cortante con SHELL 93 
Mismas líneas de comandos que II.a) sin más que modificar la definición de 
elementos: 
!Definición de elementos 
!----------------------- 
 
ET,1,SHELL93 !Elemento apropiado para el estudio de láminas curvas, 
con 8 nodos y 6 grados de libertad en cada nodo 
 
KEYOPT,1,4,0 
KEYOPT,1,5,0 
!KEYOPT,1,6,1 
KEYOPT,1,8,2 
II.c) Abolladura a lo largo del canto con ss=200mm 
!------------------------------------ 
!Ejemplo 3: -Abolladura con SHELL 63- 
!------------------------------------ 
 
FINISH 
/CLEAR 
 
/FILNAME,Abolladura del canto -No lineal-,1 
/TITLE,Pandeo por abolladura del canto del alma 
 
/prep7 
 
L=1000 !Longitud de la viga en mm 
 
!Parámetros de la sección en I 
 
w1=100 
w2=100 
w3=750 
t1=17 
t2=17 
t3=5 
t4=10 
 
!Definición del modelo sólido (keypoints) 
!---------------------------------------- 
k,1,0,0,0 
k,2,4*L/10,0,0 
k,3,L/2,0,0 
k,4,6*L/10,0,0 
k,5,L,0,0 
k,6,L,w3,0 
k,7,6*L/10,w3,0 
k,8,L/2,w3,0 
178 Proyecto Fin de Carrera Anexo III 
 
k,9,4*L/10,w3,0 
k,10,0,w3,0 
k,11,0,0,w1/2 
k,12,L,0,w1/2 
k,13,0,0,-w1/2 
k,14,L,0,-w1/2 
k,15,0,w3,w1/2 
k,16,L,w3,w1/2 
k,17,0,w3,-w1/2 
k,18,L,w3,-w1/2 
 
!líneas 
!------ 
*do,i,1,9,1 
l,i,i+1 
*enddo 
l,10,1 
l,1,11 
l,11,12 
l,12,5 
l,5,14 
l,14,13 
l,13,1 
l,10,15 
l,15,16 
l,16,6 
l,6,18 
l,18,17 
l,17,10 
l,15,11 
l,13,17 
l,16,12 
l,14,18 
 
!Áreas 
!----- 
AL,1,2,3,4,5,6,7,8,9,10 
AL,11,12,13,4,3,2,1 
AL,14,15,16,1,2,3,4 
AL,17,18,19,6,7,8,9 
AL,20,21,22,9,8,7,6 
AL,17,23,11,10 
AL,16,24,22,10 
AL,19,25,13,5 
AL,14,26,20,5 
 
!Definición de elementos 
!----------------------- 
 
ET,1,SHELL63 
 
KEYOPT,1,1,0 
KEYOPT,1,2,1 
Abolladura 179 
 
KEYOPT,1,3,2 
KEYOPT,1,8,1 
KEYOPT,1,11,2 
 
!Constantes reales 
!----------------- 
 
!Alas 
R,1,t1, , , ,0, , 
RMORE, , , , , , , 
RMORE, , , , , , , 
RMORE, , 
 
!Alma 
R,2,t3, , , ,0, , 
RMORE, , , , , , , 
RMORE, , , , , , , 
RMORE, , 
 
!Rigidizadores 
R,3,t4, , , ,0, , 
RMORE, , , , , , , 
RMORE, , , , , , , 
RMORE, , 
 
!Definición material 1 (acero) 
!----------------------------- 
MP,EX,1,21e4 
MP,PRXY,1,0.3 
MP,DENS,1,7800e-9 
 
!Propiedades de las líneas 
!------------------------- 
ASEL,S,area, ,1 
AATT,1,2,1, , , 
 
ASEL,S,area, ,2,5,1 
AATT,1,1,1, , , 
 
ASEL,S,area, ,6,9,1 
AATT,1,3,1, , , 
 
!Numero de divisiones 
LESIZE,1, , ,8, , , , ,no 
LESIZE,2, , ,2, , , , ,no 
LESIZE,3, , ,2, , , , ,no 
LESIZE,4, , ,8, , , , ,no 
LESIZE,5, , ,15, , , , ,no 
LESIZE,6, , ,8, , , , ,no 
LESIZE,7, , ,2, , , , ,no 
LESIZE,8, , ,2, , , , ,no 
LESIZE,9, , ,8, , , , ,no 
LESIZE,10, , ,15, , , , ,no 
180 Proyecto Fin de Carrera Anexo III 
 
LESIZE,12, , ,20, , , , ,no 
LESIZE,15, , ,20, , , , ,no 
LESIZE,18, , ,20, , , , ,no 
LESIZE,21, , ,20, , , , ,no 
LSEL,S, , ,23,26,1 
LESIZE,ALL, , ,15, , , , ,no 
LSEL,S, , ,11,13,2 
LESIZE,ALL, , ,3, , , , ,no 
LSEL,S, , ,14,16,2 
LESIZE,ALL, , ,3, , , , ,no 
LSEL,S, , ,17,19,2 
LESIZE,ALL, , ,3, , , , ,no 
LSEL,S, , ,20,22,2 
LESIZE,ALL, , ,3, , , , ,no 
 
!Mallado 
!------- 
allsel 
AMAP,1,1,5,6,10 
AMAP,2,1,11,12,5 
AMAP,3,5,14,13,1 
AMAP,4,10,15,16,6 
AMAP,5,6,18,17,10 
AMAP,6,10,15,11,1 
AMAP,7,1,13,17,10 
AMAP,8,6,16,12,5 
AMAP,9,5,14,18,6 
 
Finish 
allsel 
 
!Plot controls menú 
!------------------ 
 
/VIEW, ,1,1,1 !Vista ISOMÉTRICA 
/SHRINK,0.0 
/ESHAPE, 
 EPLOT 
/EFACET,1 
/RATIO,1,1.0,1.0 
/CFORMAT,32,0 
/WAIT,2 
 
!----------------- 
!Análisis estático 
!----------------- 
/Solu 
 
ANTYPE,0 
 
PIVCHECK,ON 
PSTRES,ON 
 
Abolladura 181 
 
!Condiciones de contorno en desplazamiento y fuerzas aplicadas 
!------------------------------------------------------------- 
allsel 
 
!DESPLAZAMIENTOS 
DL,2, ,UX,0 
DL,2, ,UY,0 
DL,2, ,UZ,0 
DL,2, ,ROTX,0 
DL,2, ,ROTY,0 
DL,2, ,ROTZ,0 
DL,3, ,UY,0 
DL,3, ,UZ,0 
DL,3, ,ROTX,0 
DL,3, ,ROTY,0 
DL,3, ,UX,0 
DL,3, ,ROTZ,0 
 
!DK,3,ALL,0 
DK,8,UZ,0 
 
!CARGAS 
!NSEL,S,LOC,X,4*L/8,6*L/8 
!NSEL,R,LOC,Y,w3,w3 
!NSEL,R,LOC,Z,0,0 
!F,ALL,FY,-1 
 
LSEL,S, , ,7,8,1 
SFL,ALL,PRES,1 
 
!FK,8,FY,-1 
 
!ACEL,0,9.8,0 
 
allsel 
SAVE 
 
Solve 
Finish 
 
!Análisis de pandeo 
!------------------ 
/Solu 
 
ANTYPE, buckle 
BUCOPT,LANB,3, , 
MXPAND,3, , ,yes, , 
 
Solve 
Finish 
/POST1 
 
SET,FIRST 
182 Proyecto Fin de Carrera Anexo III 
 
PLDISP,1 
/WAIT,2 
 
/VIEW, ,0,0,1 
PLNSOL,U,Z,0,1.2, , 
 
*GET,PCRIT,active,0,set, 
SAVE 
 
!------------------ 
!Análisis NO LINEAL 
!------------------ 
/prep7 
 
UPGEOM,0.5,1,1,Abolladura del canto -No lineal-,rst 
 
!allsel 
!SFLDELE,ALL,ALL 
LSEL,S, , ,7,8,1 
SFL,ALL,PRES,1.5*PCRIT 
!FK,8,FY,-1.5*PCRIT/Solu 
 
ANTYPE,STATIC 
NLGEOM,ON 
!KBC,0 
OUTRES,all,all 
NSUBST,500 
NEQIT,50 
!AUTOTS,ON 
!LNSRCH,ON 
!NCNV,2,500,8000, ,300 
 
ARCLEN,ON 
ARCTRM,U,40, ,UZ 
 
Solve 
Finish 
 
/POST1 
 
/VIEW, ,1,1,1 
SET,last 
/DSCALE,1,7 
PLDISP,0 
/WAIT,2 
 
Finish 
 
!Gráficas 
!-------- 
/POST26 
Abolladura 183 
 
FILE,Abolladura del canto -No lineal-,rst, , 
/UI,COLL,1 
 
!Definición de nuevas variables 
 
SOLU,2,NCMIT 
STORE,MERGE 
PROD,2,1, , ,CARGA, , ,1.5*PCRIT 
 
SOLU,3,NCMIT 
STORE,MERGE 
NSOL,3,204,U,Z, , 
 
ABS,4,3, , ,UZ_max 
 
SOLU,5,NCMIT 
STORE,MERGE 
 
!Defino los parámetros de las gráficas a representar 
 
PLTIME, , , 
 
/COLOR,CURVE,BLUE,1, , , 
/COLOR,GRBAK,WHIT, , , , 
 
XVAR,4 
/AXLAB,X,UZ MAXIMO (mm) 
/AXLAB,Y,Carga (N) 
/XRANGE, ,20 
PLVAR,2 
 
/WAIT,4 
PRVAR,2,4, , , , , 
III.c) Abolladura a lo largo del canto con SHELL93 y ss  200mm 
En el apartado de condiciones de contornos y fuerzas aplicadas pueden modificarse 
las restricciones de movimiento aplicadas (desmarcando los comandos marcados y 
viceversa), así como las cargas, para adaptar el modelo a los distintos estudios 
plateados con diferentes valores del ss. Del mismo modo también se puede cambiar la 
definición de keypoints para conseguir diferentes valores de ss. Así por ejemplo: 
Para ss=200mm: 
 ... 
k,2,4*L/10,0,0 
k,3,L/2,0,0 
k,4,6*L/10,0,0 
k,5,L,0,0 
k,6,L,w3,0 
k,7,6*L/10,w3,0 
k,8,L/2,w3,0 
k,9,4*L/10,w3,0 
 ... 
Para ss=100mm: 
 ... 
k,2,9*L/20,0,0 
k,3,L/2,0,0 
k,4,11*L/20,0,0 
k,5,L,0,0 
k,6,L,w3,0 
k,7,11*L/20,w3,0 
k,8,L/2,w3,0 
k,9,9*L/20,w3,0 
 ... 
184 Proyecto Fin de Carrera Anexo III 
 
Los cambios de elemento se realizarán del mismo modo que en apartados anteriores. 
III.d) Abolladura local con ss=250mm 
!------------------------------------ 
!Ejemplo 3: -Abolladura con SHELL 63- 
!------------------------------------ 
FINISH 
/CLEAR 
 
/FILNAME,Abolladura_local,1 
/TITLE,Pandeo por abolladura localizada 
 
/prep7 
 
L=9000 !Longitud de la viga en mm 
 
!Parámetros de la sección en I 
 
w1=800 
w2=800 
w3=1000 
t1=60 
t2=60 
t3=12 
t4=18 
 
!Definición del modelo sólido (keypoints) 
!---------------------------------------- 
k,1,0,0,0 
k,2,L/3,0,0 
k,3,2*L/3,0,0 
k,4,L,0,0 
k,5,L,w3/2,0 
k,6,L,w3,0 
k,7,2*L/3,w3,0 
k,8,37*L/72,w3,0 
k,9,L/2,w3,0 
k,10,35*L/72,w3,0 
k,11,L/3,w3,0 
k,12,0,w3,0 
k,13,0,w3/2,0 
k,14,0,0,w1/2 
k,15,L/3,0,w1/2 
k,16,2*L/3,0,w1/2 
k,17,L,0,w1/2 
k,18,0,0,-w1/2 
k,19,L/3,0,-w1/2 
k,20,2*L/3,0,-w1/2 
k,21,L,0,-w1/2 
k,22,0,w3,w2/2 
k,23,L/3,w3,w2/2 
k,24,2*L/3,w3,w2/2 
Abolladura 185 
 
k,25,L,w3,w2/2 
k,26,0,w3,-w2/2 
k,27,L/3,w3,-w2/2 
k,28,2*L/3,w3,-w2/2 
k,29,L,w3,-w2/2 
 
!líneas 
!------ 
*do,i,1,12,1 
l,i,i+1 
*enddo 
l,13,1 
l,1,14 
*do,i,14,16,1 
l,i,i+1 
*enddo 
l,17,4 
l,1,18 
*do,i,18,20,1 
l,i,i+1 
*enddo 
l,21,4 
l,12,22 
*do,i,22,24,1 
l,i,i+1 
*enddo 
l,25,6 
l,12,26 
*do,i,26,28,1 
l,i,i+1 
*enddo 
l,2,11 
l,3,7 
l,29,6 
l,22,14 
l,26,18 
l,25,17 
l,29,21 
l,11,23 
l,7,24 
l,11,27 
l,7,28 
*do,i,2,3,1 
l,i,i+13 
*enddo 
*do,i,2,3,1 
l,i,i+17 
*enddo 
l,15,23 
l,16,24 
l,20,28 
l,19,27 
 
186 Proyecto Fin de Carrera Anexo III 
 
!Áreas 
!----- 
AL,1,33,11,12,13 
AL,2,34,7,8,9,10,33 
AL,3,4,5,6,34 
AL,44,15,14,1 
AL,45,16,44,2 
AL,18,17,45,3 
AL,47,22,23,3 
AL,46,21,47,2 
AL,19,20,46,1 
AL,24,25,40,11 
AL,40,26,41,7,8,9,10 
AL,41,27,28,6 
AL,43,32,35,6 
AL,42,31,43,7,8,9,10 
AL,29,30,42,11 
AL,24,36,14,13,12 
AL,29,12,13,19,37 
AL,28,38,18,4,5 
AL,35,4,5,23,39 
AL,40,48,44,33 
AL,42,33,46,51 
AL,41,49,45,34 
AL,43,34,47,50 
 
!Definición de elementos 
!----------------------- 
ET,1,SHELL63 
 
KEYOPT,1,1,0 
KEYOPT,1,2,1 
KEYOPT,1,3,2 
KEYOPT,1,8,1 
KEYOPT,1,11,2 
 
!Constantes reales 
!----------------- 
 
!Alas 
R,1,t1, , , ,0, , 
RMORE, , , , , , , 
RMORE, , , , , , , 
RMORE, , 
 
!Alma 
R,2,t3, , , ,0, , 
RMORE, , , , , , , 
RMORE, , , , , , , 
RMORE, , 
 
!Rigidizadores 
R,3,t4, , , ,0, , 
Abolladura 187 
 
RMORE, , , , , , , 
RMORE, , , , , , , 
RMORE, , 
 
!Definición material 1 (acero) 
!----------------------------- 
MP,EX,1,21e4 
MP,PRXY,1,0.3 
MP,DENS,1,7800e-9 
 
!Propiedades de las líneas 
!------------------------- 
ASEL,S,area, ,1,3,1 
AATT,1,2,1, , , 
 
ASEL,S,area, ,4,15,1 
AATT,1,1,1, , , 
 
ASEL,S,area, ,16,23,1 
AATT,1,3,1, , , 
 
!Numero de divisiones 
allsel 
 
LESIZE,12, , ,15, , , , ,1 
LESIZE,13, , ,15, , , , ,1 
LESIZE,4, , ,15, , , , ,1 
LESIZE,5, , ,15, , , , ,1 
 
LESIZE,33, , ,50, , , , ,1 
LESIZE,34, , ,50, , , , ,1 
 
LESIZE,2, , ,48, , , , ,1 
LESIZE,7, , ,22, , , , ,1 
LESIZE,8, , ,2, , , , ,1 
LESIZE,9, , ,2, , , , ,1 
LESIZE,10, , ,22, , , , ,1 
 
LESIZE,1, , ,15, , , , ,1 
LESIZE,3, , ,15, , , , ,1 
LESIZE,6, , ,15, , , , ,1 
LESIZE,11, , ,15, , , , ,1 
LESIZE,15, , ,15 
LESIZE,17, , ,15 , , , ,1 
LESIZE,20, , ,15, 
LESIZE,22, , ,15, , , , ,1 
LESIZE,25, , ,15, 
LESIZE,27, , ,15, , , , ,1 
LESIZE,30, , ,15, 
LESIZE,32, , ,15, , , , ,1 
 
LESIZE,28, , ,5, , , , ,1 
LESIZE,35, , ,5, , , , ,1 
188 Proyecto Fin de Carrera Anexo III 
 
LESIZE,18, , ,5, , , , ,1 
LESIZE,23, , ,5, , , , ,1 
LSEL,S,LINE, ,24,29,5 
LESIZE,all, , ,5, , , , ,1 
LSEL,S,LINE, ,40,43,1 
LESIZE,all, , ,5, , , , ,1 
LSEL,S,LINE, ,14,19,5 
LESIZE,all, , ,5, , , , ,1 
LSEL,S,LINE, ,44,47,1 
LESIZE,all, , ,5, , , , ,1 
 
LSEL,S, , ,36,39,1 
LESIZE,all, , ,30, , , , ,1 
 
LSEL,S,LINE, ,48,51,1 
LESIZE,all, , ,50, , , , ,1 
 
!Mallado 
!------- 
allsel 
AMAP,1,1,2,11,12 
AMAP,2,2,3,7,11 
AMAP,3,3,4,6,7 
AMAP,4,2,15,14,1 
AMAP,5,3,16,15,2 
AMAP,6,4,17,16,3 
AMAP,7,21,4,3,20 
AMAP,8,20,3,2,19 
AMAP,9,19,2,1,18 
AMAP,10,12,22,23,11 
AMAP,11,11,23,24,7 
AMAP,12,7,24,25,6 
AMAP,13,6,29,28,7 
AMAP,14,7,28,27,11 
AMAP,15,11,27,26,12 
AMAP,16,12,22,14,1 
AMAP,17,26,12,1,18 
AMAP,18,6,25,17,4 
AMAP,19,29,6,4,21 
AMAP,20,11,23,15,2 
AMAP,21,27,11,2,19 
AMAP,22,7,24,16,3 
AMAP,23,28,7,3,20 
 
Finish 
allsel 
 
!Plot controls menú 
!------------------ 
 
!/VIEW, ,1,1,1 !Vista ISOMÉTRICA 
!/SHRINK,0.0 
!/ESHAPE,1 
Abolladura 189 
 
!EPLOT 
!/EFACET,1 
!/RATIO,1,1.0,1.0 
!/CFORMAT,32,0 
 
!Análisis estático 
!----------------- 
/Solu 
 
ANTYPE,0 
 
PIVCHECK,ON 
PSTRES,ON 
 
!Condiciones de contorno en desplazamiento y fuerzas aplicadas 
!------------------------------------------------------------- 
allsel 
 
!!DK,5,UX,0, , ,UY,UZ,ROTX,ROTY 
!DK,11,UX,0, , ,UY,UZ,ROTX,ROTY 
!DK,5,UZ,0 
!DK,9,UZ,0 
 
!DOFSEL,s,UX,UY,UZ,ROTX,ROTY 
DL,14, ,UX,0 
DL,14, ,UY,0 
DL,14, ,UZ,0 
DL,14, ,ROTX,0 
DL,14, ,ROTY,0 
DL,19, ,UX,0 
DL,19, ,UY,0 
DL,19, ,UZ,0 
DL,19, ,ROTX,0 
DL,19, ,ROTY,0 
DL,18, ,UX,0 
DL,18, ,UY,0 
DL,18, ,UZ,0 
DL,18, ,ROTX,0 
DL,18, ,ROTY,0 
DL,23, ,UX,0 
DL,23, ,UY,0 
DL,23, ,UZ,0 
DL,23, ,ROTX,0 
DL,23, ,ROTY,0 
 
!ELEGIR CUALQUIERA DE LAS 3 OPCIONES DE APLICACIÓN DE LA CARGA 
 
!NSEL,S,LOC,X,1375,1625 !39 nodos, por lo que tendré quemultiplicar 
el factor de pandeo resultante por 39 
!NSEL,R,LOC,Y,1000,1000 
!NSEL,R,LOC,Z,0,0 
!F,ALL,FY,-1 
 
190 Proyecto Fin de Carrera Anexo III 
 
ksel,s, , ,8,10,1 
FK,all,FY,-1 
 
!LSEL,S, , ,8,9,1 
!SFL,all,PRES,1,1,1,1 
!-------------------- 
 
!ACEL,0,9.8,0 
 
allsel 
SAVE 
 
Solve 
Finish 
 
!Análisis de pandeo 
!------------------ 
/Solu 
 
ANTYPE, buckle 
BUCOPT,LANB,2, , 
MXPAND,2, , ,yes, , 
 
Solve 
Finish 
 
/POST1 
 
SET,FIRST 
PLDISP,0 
/WAIT,2 
PLNSOL,U,Z,0,1.2, , 
 
*GET,PCRIT,active,0,set,freq 
!SET,LIST 
SAVE 
 
!------------------ 
!Análisis NO LINEAL 
!------------------ 
/prep7 
 
UPGEOM,0.5,1,1,Prueba6_No lineal,rst 
 
allsel 
FKDELE,all,all 
ksel,s, , ,8,10,1 
FK,all,FY,-1.8*PCRIT 
 
/Solu 
ANTYPE,STATIC 
NLGEOM,ON 
OUTRES,all,all 
Abolladura 191 
 
NSUBST,500 
NEQIT,50 
!AUTOTS,ON 
!LNSRCH,ON 
!NCNV,2,500,8000, ,300 
 
ARCLEN,ON 
ARCTRM,U,25, ,UZ 
 
Solve 
Finish 
 
/POST1 
 
/VIEW, 
SET,last 
/DSCALE,1,8 
PLDISP,0 
/WAIT,4 
 
Finish 
 
!Gráficas 
!-------- 
 
/POST26 
 
FILE,Prueba6_No lineal,rst, , 
 
!Definición de nuevas variables 
 
SOLU,2,NCMIT 
STORE,MERGE 
 
PROD,2,1, , ,CARGA, , ,3*(1.8*PCRIT) !MULTIPLICO POR 3 SI HE 
APLICADO LA CARGA “REPARTIDA” SOBRE LOS 3 KEYPOINTS. Por lo que la 
carga resultante será el factor de pandeo obtenido x3 
 
SOLU,3,NCMIT 
STORE,MERGE 
NSOL,3,2116,U,Z, , 
 
ABS,4,3, , ,UZ_max 
 
SOLU,5,NCMIT 
STORE,MERGE 
 
PLTIME, , , !Rango de tiempo a representar en la gráfica (por 
defecto desde el 1er punto tomado hasta el último) 
 
/COLOR,CURVE,BLUE,1, , , 
/COLOR,GRBAK,WHIT, , , , 
 
192 Proyecto Fin de Carrera Anexo III 
 
XVAR,4 !Variable 4 (UZ máximo) representado en el eje X 
 
/AXLAB,X,UZ MAXIMO (mm) 
/AXLAB,Y,Carga (N) 
/XRANGE, ,24 
/YRANGE, ,8500000 
 
PLVAR,2 
/WAIT,4 
 
PRVAR,2,4, , , , , 
III.e) Abolladura local con ss=500mm 
Bastará modificar la ubicación de alguno de los keypoints definidos anteriormente para 
conseguir el modelo adaptado al estudio de cargas repartidas sobre 500mm. Así, se 
tiene: 
 ... 
k,7,2*L/3,w3,0 
k,8,38*L/72,w3,0 
k,9,L/2,w3,0 
k,10,34*L/72,w3,0 
k,11,L/3,w3,0 
 ... 
 
 
Para esta nueva disposición, el borde superior del rectángulo central quedará 
compuesto por 2 líneas “largas” y 2 “cortas” al igual que en el apartado d), pero en 
este caso la relación de longitudes será de 10 a 2, en lugar de 11 a 1 como ocurría 
anteriormente, por lo que si queremos realizar un mallado mapeado simétrico 
deberemos modificar los parámetros de mallado de las líneas: 
 ... 
LESIZE,2, , ,48, , , , ,1 
LESIZE,7, , ,20, , , , ,1 
LESIZE,8, , ,4, , , , ,1 
LESIZE,9, , ,4, , , , ,1 
LESIZE,10, , ,20, , , , ,1 
 ... 
III.f) Placa uniformemente comprimida 
!---------------------------------------- 
!Ejemplo 3: -Pandeo de Placa con SHELL93- 
!---------------------------------------- 
 
FINISH 
/CLEAR 
 
/FILNAME,Pandeo_Placa,1 
/TITLE,Pandeo Placa -lineal- 
 
 
Abolladura 193 
 
/prep7 
 
a=200 
b=100 
t=2 
 
!Definición del modelo sólido (keypoints) 
!---------------------------------------- 
RECTNG,0,a,0,b 
 
!Definición de elementos 
!----------------------- 
ET,1,SHELL93 !Elemento de 8 nodos (plano medio de la placa) 
especialmente adecuado para el modelado de placas curvas. Define 6 
grados de libertad en cada nodo, y deformadas cuadráticas en ambas 
direcciones del plano del elemento. Adecuado además para la 
consideración de grandes desplazamientos. 
 
!Definición de las constantes reales 
!----------------------------------- 
R,1,t,t,t,t, , , 
 
!Definición material 1 (acero) 
!----------------------------- 
MP,EX,1,21e4 
MP,PRXY,1,0.3 
!No necesito definir la densidad del material, puesto que no se van a 
considerar las fuerzas de peso propio 
 
!Propiedades de las líneas 
!------------------------- 
allsel 
 
LSEL, , , ,2,4,2 
LESIZE,all, , ,20, , , , ,1 
LSEL, , , ,1,3,2 
LESIZE,all, , ,30, , , , ,1 
 
!Mallado 
!------- 
allsel 
AMAP,1,1,2,3,4 
 
!Plot controls menú 
!------------------ 
 
/SHRINK,0.0 
/ESHAPE,1 
EPLOT 
/EFACET,1 
/RATIO,1,1.0,1.0 
/CFORMAT,32,0 
 
194 Proyecto Fin de Carrera Anexo III 
 
!----------------- 
!Análisis estático 
!----------------- 
/Solu 
 
ANTYPE,0 
PIVCHECK,ON 
PSTRES,ON 
 
!Condiciones de contorno en desplazamiento 
!----------------------------------------- 
allsel 
 
LSEL, , , ,1,4,1 
DL,all, ,UZ,0, , 
 
allsel 
!DK,all,UY,0 
DL,1, ,UY,0, , 
DL,4, ,UX,0, , 
 
LSEL, , , ,2,4,2 
SFL,all,PRES,1,1, , , 
allsel 
 
SAVE 
Solve 
Finish 
 
!------------------ 
!Análisis de pandeo 
!------------------ 
/Solu 
 
ANTYPE, buckle 
BUCOPT,SUBSP,5, , , 
SUBOPT,8,4,0,100, ,all !Ver ayuda de SUBOPT 
MXPAND,5, , ,yes, , 
Solve 
 
/POST1 
 
/VIEW, ,1,1,1 
SET,FIRST 
PLDISP,1 
/WAIT,4 
 
PLNSOL,U,Z,0, , , !Equivale a la orden 'contour plot' del menú 
/WAIT,4 
 
SET,NEXT 
PLDISP,1 
/WAIT,4 
Abolladura 195 
 
PLNSOL,U,Z,0, , , 
/WAIT,4 
 
SET,NEXT 
PLDISP,1 
/WAIT,4 
 
PLNSOL,U,Z,0, , , 
 
Finish